AC_INIT(diction.c)
AC_CONFIG_HEADER(config.h)
AC_CANONICAL_HOST
VERSION=1.03
UPDATED='April 8, 2003'

ALL_LINGUAS="de"

if test "$prefix" = NONE
then
  case $host in
    *-linux-*)
      PIPE="-pipe "
    ;;
  esac
fi

AC_PROG_CC
if test "$GCC" = yes
then
  CFLAGS="${CFLAGS} ${PIPE}-Wno-unused -Wshadow -Wbad-function-cast -Wmissing-prototypes -Wstrict-prototypes -Wcast-align -Wcast-qual -Wpointer-arith -Wcast-align -Wwrite-strings -Wmissing-declarations -Wnested-externs -Wundef -pedantic -fno-common"
  LDFLAGS='-g'
fi

AC_PROG_INSTALL
AC_CHECK_FUNCS(strerror)

AC_MSG_CHECKING(for broken realloc)
AC_TRY_RUN([#include <sys/types.h>
#include <signal.h>
#include <stdlib.h>

static void sigsegv(int n)
{
  exit(1);
}

int main(void)
{
  signal(SIGSEGV,sigsegv);
  realloc((void*)0,1);
  exit(0);
}
],AC_MSG_RESULT(no),AC_DEFINE(BROKEN_REALLOC) AC_MSG_RESULT(yes))

USE_NLS=no
AC_CHECK_PROG(MSGFMT,msgfmt,yes,no)
if test "$MSGFMT" = yes
then
  AC_CHECK_HEADERS(libintl.h,[LIBINTL=yes])
  if test "$LIBINTL" = yes
  then
    AC_SEARCH_LIBS(gettext,intl,[AC_DEFINE(HAVE_GETTEXT) USE_NLS=yes])
  fi
fi

AC_DEFINE_UNQUOTED(VERSION,"$VERSION")
AC_SUBST(VERSION)
AC_SUBST(UPDATED)
eval DATADIR=$datadir
AC_SUBST(DATADIR)
AC_SUBST(USE_NLS)
AC_OUTPUT(Makefile diction.1 diction.texi diction.spec style.1)